<!-- #include file="APLib.asp" -->
<!-- #include file="adovbs.inc" -->
<%
'*******************************************************************************
'* xcAuction Copyright 1995-2005 XCENT - www.xcent.com                         *
'* xcAuction is a trademark of XCENT                                           *
'* This notice may not be removed from this source code file                   *
'*******************************************************************************
    Dim sSearchTerms
    Dim sArSpecialIcons
    Dim bSwitch
    lPromptWidth = 170
    sCMD = UCase(Trim(RequestValue("CMD")))
    sSearchBy = UCase(Trim(RequestValue("SEARCHBY")))
    sSearchFor = Trim(RequestValue("SEARCHFOR"))
    lCatID = FVal(RequestValue("CATID"))
    bSearchDesc = EvalBool(RequestValue("SearchDesc"))
    bSearchPremiere = EvalBool(RequestValue("SearchPremiere"))
    bSearchFeatured = EvalBool(RequestValue("SearchFeatured"))
    bSearchClosed = EvalBool(RequestValue("SearchClosed"))
    sSearchName = Trim(RequestValue("SearchName"))
    sSearchBidderName = Trim(RequestValue("SearchBidderName"))
    sSearchSerial = Trim(RequestValue("SearchSerial"))
    sSearchPart = Trim(RequestValue("SearchPart"))
    sSearchProduct = Trim(RequestValue("SearchProduct"))
    sSearchReference = Trim(RequestValue("SearchReference"))
    lPageCurrent = FVal(RequestValue("Page"))
    If lPageCurrent = 0 Then lPageCurrent = 1
    lSearchRegion = Fval(RequestValue("RegionID"))
    sView = UCase(RequestValue("VIEW"))
    If Len(Trim(sView)) = 0 Then sView = UCase(gsDefaultView)
    sSortBy = Trim(RequestValue("SortBy"))
    If Len(sSortBy) > 0 Then
        Response.Cookies("APSearchSort") = sSortBy
    Else
        If Len(Request.Cookies("APSearchSort")) > 0 Then
            sSortBy = Request.Cookies("APSearchSort")
        End If
    End If
    
    Set objErr = Server.CreateObject("Scripting.Dictionary")
    
    sTypeColImg = GLS_OrderedNone
    sTitleColImg = GLS_OrderedNone
    sBidsColImg = GLS_OrderedNone
    sClosesColImg = GLS_OrderedNone
    sCurrBidColImg = GLS_OrderedNone
    sTypeSort = "TYPE"
    sTitleSort = "TITLE"
    sBidsSort = "BIDS"
    sClosesSort = "CLOSES"
    sCurrBidSort = "CURRBID"
    
    sOrderBy = " ORDER BY aucShowFeatured DESC "
    Select Case UCase(sSortBy)
	    Case "TYPE"
	        sOrderBy = sOrderBy & ", aucType "
	        sTypeColImg = GLS_OrderedAsc
	        sTypeSort = "TYPEDESC"
	    Case "TITLE"
	        sOrderBy = sOrderBy & ", aucTitle "
	        sTitleColImg = GLS_OrderedAsc
	        sTitleSort = "TITLEDESC"
	    Case "BIDS"
	        sOrderBy = sOrderBy & ", aucBidCounts DESC"
	        sBidsColImg = GLS_OrderedDesc
	        sBidsSort = "BIDSASC"
	    Case "CURRBID"
	        sOrderBy = sOrderBy & ", aucCurrentBid DESC, aucStartingBid DESC"
	        sCurrBidColImg = GLS_OrderedDesc
	        sCurrBidSort = "CURRBIDASC"    
	    Case "CLOSES"
	        sOrderBy = sOrderBy & ", aucClose"
	        sClosesColImg = GLS_OrderedAsc
	        sClosesSort = "CLOSESDESC"
	    Case "TYPEDESC"
	        sOrderBy = sOrderBy & ", aucType DESC"
	        sTypeColImg = GLS_OrderedDesc
	        sTypeSort = "TYPE"
	    Case "TITLEDESC"
	        sOrderBy = sOrderBy & ", aucTitle DESC"
	        sTitleColImg = GLS_OrderedDesc
	        sTitleSort = "TITLE"
	    Case "BIDSASC"
	        sOrderBy = sOrderBy & ", aucBidCounts"
	        sBidsColImg = GLS_OrderedAsc
	        sBidsSort = "BIDS"
	    Case "CURRBIDASC"
	        sOrderBy = sOrderBy & ", aucCurrentBid, aucStartingBid"
	        sCurrBidColImg = GLS_OrderedAsc
	        sCurrBidSort = "CURRBID"     
	    Case "CLOSESDESC"
	        sOrderBy = sOrderBy & ", aucClose DESC"
	        sClosesColImg = GLS_OrderedDesc
	        sClosesSort = "CLOSES"
	    Case Else
	        sOrderBy = sOrderBy & ", aucClose "
	        sClosesColImg = GLS_OrderedAsc
	        sClosesSort = "CLOSESDESC"
	End Select

    
    sURLString = "&CMD=" & sCMD & "&catid=" & lCatID & "&SearchBy=" & sSearchBy & "&SearchFor=" & Server.URLEncode(sSearchFor) & _
                 "&SEARCHDESC=" & bSearchDesc & "&SearchPremiere=" & bSearchPremiere & _
                 "&SearchFeatured=" & bSearchFeatured & "&SearchName=" & sSearchName & _
                 "&SearchBidderName=" & Server.URLEncode(sSearchBidderName) & "&SearchClosed=" & bSearchClosed & _
                 "&RegionID=" & lSearchRegion & _
                 "&SearchSerial=" & Server.URLEncode(sSearchSerial) & _
                 "&SearchPart=" & Server.URLEncode(sSearchPart) & _
                 "&SearchProduct=" & Server.URLEncode(sSearchProduct) & _
                 "&SearchReference=" & Server.URLEncode(sSearchReference)

    If giAuctionEnabled Then
        OpenDBConn
       
        If NOT (gbRegistrationRequired AND NOT IsUserLoggedIn) Then	    
            Set rsAuction = Server.CreateObject("ADODB.Recordset")
            rsAuction.CursorLocation = adUseClient
            Select Case sCMD
                Case "NAME"
                    Response.Redirect "APSearch.asp?CMD=SEARCH&SearchName=" & sSearchName
                Case "LASTCHANCE"
                    sSearchSQL = "SELECT TOP " & SQLVal(giLastChanceSearchSize) & " tblAPAuctions.* " & _
                            " FROM tblAPAuctions " & _
                            " WHERE aucClose > " & SQLDate(Now) & _
                            " And aucClose <= " & SQLDate(DateAdd("n", giClosingSoon, NOW )) & _
                            " AND NOT aucStaged = " & SQLStr("Y")
                    If UCase(Trim(sView)) = "GALLERY" And (gbGalleryView And gbUseGallery) Then
                        sSearchSQL = sSearchSQL & " AND aucShowInGallery = " & SQLStr("Y")
            		ElseIf UCase(Trim(sView)) = "GALLERY" AND (gbGalleryView And Not gbUseGallery) Then
            		    sSearchSQL = sSearchSQL & " AND aucIMGFlag = " & SQLStr("Y")
                    End If
                	sSearchSQL = sSearchSQL & sOrderBy
                    'Response.Write sSQL
                    rsAuction.MaxRecords = giLastChanceSearchSize
                    rsAuction.PageSize = giLinksPerPage
                    rsAuction.Open sSearchSQL, gobjConnect, adOpenStatic, adLockReadOnly, adCmdText
                    iPageCount = rsAuction.PageCount
                    If Not rsAuction.Eof Then
                        ShowSearchResults
                    Else
                        objErr.Add "NORESULTS", Replace(gsSearchErrNoLastChance, "%CLOSINGSOON%", giClosingSoon)
                        ShowSearchForm
                    End If
                    rsAuction.Close
                    Set rsAuction = Nothing
                Case "HOT"
                    sSearchSQL = "SELECT TOP " & SQLVal(giHotSearchSize) & " tblAPAuctions.* " & _
                                 " FROM tblAPAuctions " & _
                                 " WHERE aucClose > " & SQLDate(Now)
                    If giHotCriteria = 1 Then
                        sSearchSQL = sSearchSQL & " And aucBidCounts >= " & SQLVal(giHotCount)
                    Else
                        sSearchSQL = sSearchSQL & " And aucViewCount >= " & SQLVal(giHotCount)
                    End If
                    sSearchSQL = sSearchSQL & " AND NOT aucStaged = " & SQLStr("Y")
                    If UCase(Trim(sView)) = "GALLERY" And (gbGalleryView And gbUseGallery) Then
                        sSearchSQL = sSearchSQL & " AND aucShowInGallery = " & SQLStr("Y")
            		ElseIf UCase(Trim(sView)) = "GALLERY" AND (gbGalleryView And Not gbUseGallery) Then
            		    sSearchSQL = sSearchSQL & " AND aucIMGFlag = " & SQLStr("Y")
                    End If
                	sSearchSQL = sSearchSQL & sOrderBy
                    'Response.Write sSQL
                    rsAuction.MaxRecords = giHotSearchSize
                    rsAuction.PageSize = giLinksPerPage
                    rsAuction.Open sSearchSQL, gobjConnect, adOpenStatic, adLockReadOnly, adCmdText
                    iPageCount = rsAuction.PageCount
                    If Not rsAuction.Eof Then
                        ShowSearchResults
                    Else
                        objErr.Add "NORESULTS", Replace(gsSearchErrNoHot, "%HOTCOUNT%", giHotCount & OutMatch(True, giHotCriteria = 1, " bids", " views"))
                        ShowSearchForm
                    End If
                    rsAuction.Close
                    Set rsAuction = Nothing
                Case "NEW"
                    sSearchSQL = "SELECT TOP " & SQLVal(giNewSearchSize) & " tblAPAuctions.* " & _
                            " FROM tblAPAuctions " & _
                            " WHERE aucClose > " & SQLDate(Now) & _
                            " And aucAvailable >= " & SQLDate(DateAdd("h", - giNewHours, Now)) & _
                            " AND aucAvailable <= " & SQLDate(Now) & _
                            " AND Not aucStaged = " & SQLStr("Y")
                    If UCase(Trim(sView)) = "GALLERY" And (gbGalleryView And gbUseGallery) Then
                        sSearchSQL = sSearchSQL & " AND aucShowInGallery = " & SQLStr("Y")
            		ElseIf UCase(Trim(sView)) = "GALLERY" AND (gbGalleryView And Not gbUseGallery) Then
            		    sSearchSQL = sSearchSQL & " AND aucIMGFlag = " & SQLStr("Y")
                    End If
                	sSearchSQL = sSearchSQL & sOrderBy
                    'Response.Write sSearchSQL
                    rsAuction.MaxRecords = giNewSearchSize
                    rsAuction.PageSize = giLinksPerPage
                    rsAuction.Open sSearchSQL, gobjConnect, adOpenStatic, adLockReadOnly, adCmdText
                    iPageCount = rsAuction.PageCount
                    If Not rsAuction.Eof Then
                        ShowSearchResults
                    Else
                        objErr.Add "NORESULTS", Replace(gsSearchErrNoNew, "%NEWHOURS%", giNewHours)
                        ShowSearchForm
                    End If
                    rsAuction.Close
                    Set rsAuction = Nothing
                Case "SEARCH":
                    sExcludeString = " + ? ( ) ! & * %"
                    sArExclude = Split(sExcludeString, " ")
                    sSearchString = sSearchFor
                    For iExcludeCharIndex  = 0 To UBound(sArExclude)
                        sSearchString = Replace(sSearchString, sArExclude(iExcludeCharIndex), "")
                        sSearchSerial = Replace(sSearchSerial, sArExclude(iExcludeCharIndex), "")
                        sSearchPart = Replace(sSearchPart, sArExclude(iExcludeCharIndex), "")
                        sSearchProduct = Replace(sSearchProduct, sArExclude(iExcludeCharIndex), "")
                        sSearchReference = Replace(sSearchReference, sArExclude(iExcludeCharIndex), "")
                    Next
                    If sSearchBy = "ALL" Then
                        sTerms = " AND "
                    Else
                        sTerms = " OR "
                    End If
                    If glMaxSearchResults = 0 Then
                        sSearchSQL = "SELECT tblAPAuctions.* "
                    Else
                        sSearchSQL = "SELECT TOP " & SQLVal(glMaxSearchResults) & " tblAPAuctions.* "
                    End If
                    sSearchSQL = sSearchSQL & "FROM tblAPAuctions WHERE "

                    If bSearchClosed Then
                        sSearchSQL = sSearchSQL & " aucClose < " & SQLDate(Now)
                    Else
                        sSearchSQL = sSearchSQL & " aucClose > " & SQLDate(DateAdd("n", 1, Now))
                    End If
                    
                    sSearchSQL = sSearchSQL & " AND NOT aucStaged = " & SQLStr("Y")
                    
                	iFirstIteration = True
                	If Len(sSearchString) > 0 Then
                        If giLogSearchTerms Then
                            LogEvent "SEARCH", sSearchString
                        End If
                	    sSearchTerms = Split(sSearchString, " ", -1, 1)
                    	For lLoop = 0 to ubound(sSearchTerms)
                    	    If Len(Trim(sSearchTerms(lLoop))) > 0 Then
                        	    If iFirstIteration Then
                        	        sSearchSQL = sSearchSQL & " AND ("
                        	        iFirstIteration = False
                        	    Else
                        	        sSearchSQL = sSearchSQL & sTerms
                        	    End If
                    	        'If gbFieldSearchExactMatch Then
					            '    sSearchSQL = sSearchSQL & "( aucTitle = " & SQLStr(sSearchTerms(lLoop)) & " "
				                'Else
                    	            sSearchSQL = sSearchSQL & "( aucTitle Like " & SQLStr(gsSQLWildCardChar & sSearchTerms(lLoop) & gsSQLWildCardChar) & " "
                    	        'End If
                    	        If bSearchDesc Then
                    	            sSearchSQL = sSearchSQL & " OR aucDescription Like " & SQLStr(gsSQLWildCardChar & sSearchTerms(lLoop) & gsSQLWildCardChar) & " "
                    	        End If
                    	        sSearchSQL = sSearchSQL & ") "
                    	    End If
                    	Next
                    End If
                	
                	If Len(sSearchSerial) > 0 Then
                	    'sArTempSearch = Split(sSearchSerial)
                	    'sSearchSQL = sSearchSQL & GetSearchQueryPart(sArTempSearch, sTerms, "aucSerialNo")
                	    If gbFieldSearchExactMatch Then
                	        sSearchSQL = sSearchSQL & " " & sTerms & " aucSerialNo = " & SQLStr(sSearchSerial) & " "
                	    Else
                	        sSearchSQL = sSearchSQL & " " & sTerms & " aucSerialNo Like " & SQLStr(gsSQLWildCardChar & sSearchSerial & gsSQLWildCardChar ) & " "
                	    End If
                	End If
                	If Len(sSearchPart) > 0 Then
                	    'sArTempSearch = Split(sSearchPart)
                	    'sSearchSQL = sSearchSQL & GetSearchQueryPart(sArTempSearch, sTerms, "aucPartNo")
                	    If gbFieldSearchExactMatch Then
                	        sSearchSQL = sSearchSQL & " " & sTerms & " aucPartNo = " & SQLStr(sSearchPart) & " "
                	    Else
                	        sSearchSQL = sSearchSQL & " " & sTerms & " aucPartNo Like " & SQLStr(gsSQLWildCardChar & sSearchPart & gsSQLWildCardChar ) & " "
                	    End If
                	End If
                	If Len(sSearchProduct) > 0 Then
                	    'sArTempSearch = Split(sSearchProduct)
                	    'sSearchSQL = sSearchSQL & GetSearchQueryPart(sArTempSearch, sTerms, "aucProductCode")
                	    If gbFieldSearchExactMatch Then
                	        sSearchSQL = sSearchSQL & " " & sTerms & " aucProductCode = " & SQLStr(sSearchProduct) & " "
                	    Else
                	        sSearchSQL = sSearchSQL & " " & sTerms & " aucProductCode Like " & SQLStr(gsSQLWildCardChar & sSearchProduct & gsSQLWildCardChar ) & " "
                	    End If
                	End If
                	If Len(sSearchReference) > 0 Then
                	    'sArTempSearch = Split(sSearchReference)
                	    'sSearchSQL = sSearchSQL & GetSearchQueryPart(sArTempSearch, sTerms, "aucReferenceNo")
                	    If gbFieldSearchExactMatch Then
                	        sSearchSQL = sSearchSQL & " " & sTerms & " aucReferenceNo = " & SQLStr(sSearchReference) & " "
                	    Else
                	        sSearchSQL = sSearchSQL & " " & sTerms & " aucReferenceNo Like " & SQLStr(gsSQLWildCardChar & sSearchReference & gsSQLWildCardChar ) & " "
                	    End If
                	End If
                	
                    If Not iFirstIteration Then sSearchSQL = sSearchSQL & ") "
                    
                    If Len(sSearchName) > 0 Then
                        lOwnerRegID = 0
                        Set rs = gobjConnect.Execute("SELECT regID FROM tblXUDUserRegistration WHERE regUserName = " & SQLStr(sSearchName))
                        If Not rs.Eof Then
                            lOwnerRegID = FVal(rs("regID"))
                        Else
                            'lOwnerRegID = 0
                            objErr.Add "NORESULTS", gsSearchErrNoName 
                        End If
                        rs.Close
                        Set rs = Nothing
                        If lOwnerRegID > 0 Then sSearchSQL = sSearchSQL & " AND aucOwner = " & SQLVal(lOwnerRegID)
                    End If
                    If Len(sSearchBidderName) > 0 Then
                        lBidderRegID = 0
                        Set rs = gobjConnect.Execute("SELECT regID FROM tblXUDUserRegistration WHERE regUserName = " & SQLStr(sSearchBidderName))
                        If Not rs.Eof Then
                            lBidderRegID = FVal(rs("regID"))
                        Else
                            'lBidderRegID = 0'
                            If NOT objErr.Exists("NORESULTS") Then objErr.Add "NORESULTS", gsSearchErrNoName 
                        End If
                        rs.Close
                        Set rs = Nothing
                        If lBidderRegID <> glUserID Then
                            sSearchSQL = sSearchSQL & " AND ((aucID IN (SELECT bidAucID FROM tblAPBids " & _
                                                  " WHERE bidBidderID = " & SQLVal(lBidderRegID) & ")) " & _
                                                  " AND (aucPrivateBids <> " & SQLBool("Y") & " OR aucPrivateBids Is NULL)) "
                        Else
                            sSearchSQL = sSearchSQL & " AND (aucID IN (SELECT bidAucID FROM tblAPBids " & _
                                                  " WHERE bidBidderID = " & SQLVal(lBidderRegID) & ")) "
                        End If
                        
                    End If
                	If lCatID > 0 Then
                	    sSearchSQL = sSearchSQL & " AND aucCatID = " & SQLVal(lCatID)
                	End If
                	If lSearchRegion > 0 Then
                	    sSearchSQL = sSearchSQL & " AND aucRegionID = " & SQLVal(lSearchRegion)
                	End If
                	If bSearchPremiere Then
                	    sSearchSQL = sSearchSQL & " AND aucShowInPremiere = " & SQLBool(True)
                	End If
                	If bSearchFeatured Then
                	    sSearchSQL = sSearchSQL & " AND aucShowFeatured = " & SQLBool(True)
                	End If
                    If UCase(Trim(sView)) = "GALLERY" And (gbGalleryView And gbUseGallery) Then
                        sSearchSQL = sSearchSQL & " AND aucShowInGallery = " & SQLStr("Y")
            		ElseIf UCase(Trim(sView)) = "GALLERY" AND (gbGalleryView And Not gbUseGallery) Then
            		    sSearchSQL = sSearchSQL & " AND aucIMGFlag = " & SQLStr("Y")
                    End If
                	
                	sSearchSQL = sSearchSQL & sOrderBy
    
                    'response.write "sSearchSQL:<br>" & sSearchSQL & "<br><br>"
                    If objErr.Count = 0 Then
                	    rsAuction.PageSize = giLinksPerPage
                    	rsAuction.Open sSearchSQL, gobjConnect, adOpenStatic, adLockReadOnly, adCmdText
                    	iPageCount = rsAuction.PageCount
                        
                        If Not rsAuction.Eof Then
                            ShowSearchResults
                        Else
                            objErr.Add "NORESULTS", gsSearchErrNoResults
                            ShowSearchForm
                        End If
                        rsAuction.Close
                        Set rsAuction = Nothing
                   Else
                        ShowSearchForm
                   End If     
                Case Else
                    ShowSearchForm
            End Select
            CloseDBConn
          Else
          		Response.Redirect "APRegistrationRequired.asp"
          End If
    Else
        Response.Redirect "APDisabled.asp"
    End If
    Set objErr = Nothing

Sub ShowSearchForm
    DoPageHeader
    PageHead(False)
    TableHead False, gsSearchCriteria, False
    Response.Write "<br>"
    
    ContentHead 3, False
    Response.Write vbCrLf & vbCrLf & "<script language=""JavaScript"">" & vbCrLf
    Response.Write "<!--" & vbCrLf
    Response.Write "function AP_SelectCategory() {" & vbCrLf
    Response.Write "    chosen = document.EDITFORM.CatID.selectedIndex" & vbCrLf
    Response.Write "    if(chosen==1) {" & vbCrLf
    Response.Write "        lCurrentCatID = document.EDITFORM.CatID.options[0].value;" & vbCrLf
    Response.Write "        document.EDITFORM.CatID.selectedIndex = 0;" & vbCrLf
    Response.Write "        var apPickWindow = window.open('APPickCategory.asp?id=' + lCurrentCatID,'APPickCat','" & gsPickCatWindowParams & "');" & vbCrLf
    Response.Write "        apPickWindow.focus();" & vbCrLf
    'Response.Write "    } else {" & vbCrLf
    'Response.Write "        document.EDITFORM.ShowCatIDChoice.value = document.EDITFORM.CatID.options[chosen].text;" & vbCrLf
    'Response.Write "        document.EDITFORM.ShowCatIDValue.value = document.EDITFORM.CatID.options[chosen].value;" & vbCrLf
    Response.Write "    }" & vbCrLf
    Response.Write "}" & vbCrLf
    Response.Write "// -->" & vbCrLf
    Response.Write "</script>" & vbCrLf
	Response.Write "<FORM METHOD=""POST"" ACTION=""APSearch.asp"" NAME=""EDITFORM"">"
	Response.Write "<INPUT TYPE=""HIDDEN"" NAME=""CMD"" VALUE=""SEARCH"">"
	If objErr.Exists("NORESULTS") Then
	    Response.Write "<TR><TD COLSPAN=""2"">" & objErr.Item("NORESULTS") & "</TD></TR>"
	End If
	Response.Write "<tr><td colspan=""2"">" & gsPlainTextOpen & GLS_SearchInstructions & gsPlainTextClose & "</td></tr>"
	Response.Write "<TR><TD WIDTH=""20%"">" & gsFormTextOpen & GLS_SearchWords & gsFormTextClose & "</TD>"
	Response.Write "<TD><INPUT TYPE=""TEXT"" NAME=""SearchFor"" VALUE=""" & Server.HTMLEncode(sSearchFor) & """ SIZE=""40""></TD></TR>"
    Response.Write "<TR><TD WIDTH=""20%"">" & gsFormTextOpen & GLS_SearchUserName & gsFormTextClose & "</TD>"
    Response.Write "<TD><INPUT TYPE=""TEXT"" NAME=""SearchName"" VALUE=""" & Server.HTMLEncode(sSearchName) & """></TD></TR>"
    Response.Write "<TR><TD WIDTH=""20%"">" & gsFormTextOpen & GLS_SearchBidder & gsFormTextClose & "</TD>"
    Response.Write "<TD><INPUT TYPE=""TEXT"" NAME=""SearchBidderName"" VALUE=""" & Server.HTMLEncode(sSearchBidderName) & """></TD></TR>"

    If gbShowSerialNo Then
        Response.Write "<TR><TD WIDTH=""20%"">" & gsFormTextOpen & GLS_SearchBySerial & gsFormTextClose & "</TD>"
        Response.Write "<TD><INPUT TYPE=""TEXT"" NAME=""SearchSerial"" VALUE=""" & Server.HTMLEncode(sSearchSerial) & """></TD></TR>"
    End If
    If gbShowPartNo Then
        Response.Write "<TR><TD WIDTH=""20%"">" & gsFormTextOpen & GLS_SearchByPart & gsFormTextClose & "</TD>"
        Response.Write "<TD><INPUT TYPE=""TEXT"" NAME=""SearchPart"" VALUE=""" & Server.HTMLEncode(sSearchPart) & """></TD></TR>"
    End If
    If gbShowProductCode Then
        Response.Write "<TR><TD WIDTH=""20%"">" & gsFormTextOpen & GLS_SearchByProduct & gsFormTextClose & "</TD>"
        Response.Write "<TD><INPUT TYPE=""TEXT"" NAME=""SearchProduct"" VALUE=""" & Server.HTMLEncode(sSearchProduct) & """></TD></TR>"
    End If
    If gbShowReferenceNo Then
        Response.Write "<TR><TD WIDTH=""20%"">" & gsFormTextOpen & GLS_SearchByReference & gsFormTextClose & "</TD>"
        Response.Write "<TD><INPUT TYPE=""TEXT"" NAME=""SearchReference"" VALUE=""" & Server.HTMLEncode(sSearchReference) & """></TD></TR>"
    End If
    
    Response.Write "<tr><td width=""20%"" valign=""top"">" & gsFormTextOpen & GLS_SearchByCategory & gsFormTextClose & "</td>"
    Response.Write "<td>" & gsPLainTextOpen
    If gbDropDownCatSelect OR gbSearchTopLevelCatsOnly Then
		Response.Write GetCatDropDown(lCatID, gbSearchTopLevelCatsOnly, "")
    Else
        Response.Write "<SELECT name=""CatID"" onChange=""AP_SelectCategory(); return false;"">"
        If lCatID <> 0 Then
    	    Response.Write "<OPTION value=""" & lCatID & """>" & GetCatPath(lCatID, False, "") & "</OPTION>"
    	Else
    	    Response.Write "<OPTION value=""0"">" & GLS_TextNoCatSel & "</OPTION>"
	    End If
    	Response.Write "<OPTION value=""-1"">" & GLS_TextPickNewCategory & "&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;</OPTION>"
        Response.Write "</SELECT>"
		Response.Write "<br>" & gsHintTextOpen & GLS_FormCatFieldHint & gsHintTextClose
	End If
    Response.Write gsPlainTextClose & "</td></tr>"
    
	'Region DropDown
	If gbShowRegion Then
		Response.Write "<TR><TD WIDTH=""20%"">" & gsFormTextOpen & GLS_SearchRegion & gsFormTextClose & "</TD>"
		Response.Write "<TD>"
		DoRegionDropDown
		Response.Write "</TD></TR>"
	End If 

	Response.Write "<TR><TD WIDTH=""20%"">&nbsp;</TD><TD><SELECT NAME=""SearchBy"">"
	Response.Write "<OPTION VALUE=""ALL"" " & OutMatch("ALL", sSearchBy, "SELECTED", "") & ">" & GLS_SearchAllWords & "</OPTION>"
	Response.Write "<OPTION VALUE=""ANY"" " & OutMatch("ANY", sSearchBy, "SELECTED", "") & ">" & GLS_SearchAnyWords & "</OPTION>"
	Response.Write "</SELECT></TD></TR>"
		
	Response.Write "<TR><TD WIDTH=""20%""><FONT SIZE=""1"">&nbsp;</TD><TD>" & gsPlainTextOpen & "<INPUT TYPE=""CHECKBOX"" NAME=""SEARCHDESC"" VALUE=""Y"" " & OutMatch(True, bSearchDesc, "CHECKED", "") & ">&nbsp;" & GLS_SearchOptionTND & gsPlainTextClose & "</TD></TR>"
	If gbUsePremiere Then
		Response.Write "<TR><TD WIDTH=""20%""><FONT SIZE=""1"">&nbsp;</TD><TD>" & gsPlainTextOpen & "<INPUT TYPE=""CHECKBOX"" NAME=""SEARCHPremiere"" VALUE=""Y"" " & OutMatch(True, bSearchPremiere, "CHECKED", "") & ">&nbsp;" & GLS_SearchOptionPremiere & gsPlainTextClose & "</TD></TR>"
	End If
	If gbUseFeatured Then
		Response.Write "<TR><TD WIDTH=""20%""><FONT SIZE=""1"">&nbsp;</TD><TD>" & gsPlainTextOpen & "<INPUT TYPE=""CHECKBOX"" NAME=""SEARCHFEATURED"" VALUE=""Y"" " & OutMatch(True, bSearchFeatured, "CHECKED", "") & ">&nbsp;" & GLS_SearchOptionFeatured & gsPlainTextClose & "</TD></TR>"
	End If
	Response.Write "<TR><TD WIDTH=""20%""><FONT SIZE=""1"">&nbsp;</TD><TD>" & gsPlainTextOpen & "<INPUT TYPE=""CHECKBOX"" NAME=""SEARCHCLOSED"" VALUE=""Y"" " & OutMatch(True, bSearchClosed, "CHECKED", "") & ">&nbsp;" & GLS_SearchOptionClosed & gsPlainTextClose & "</TD></TR>"

	Response.Write "<TR><TD WIDTH=""20%"">&nbsp;</TD><TD><INPUT TYPE=""submit"" VALUE=""" & GLS_TextSearch & """ CLASS=""XcBtn""></TD></TR>"
	Response.Write "</FORM>"
	ContentTail

    Response.Write "<br>"
    
    'By Lot Search
    ContentHead 3, False
    Response.Write "<FORM METHOD=""POST"" ACTION=""APViewItem.asp"" >"
    Response.Write "<TR><TD WIDTH=""20%"">" & gsFormTextOpen & GLS_SearchLotNo & gsFormTextClose & "</TD>"
    Response.Write "<TD><INPUT TYPE=""TEXT"" NAME=""ID"" VALUE=""""></TD></TR>"
    Response.Write "<TR><TD WIDTH=""20%"">&nbsp;</TD><TD><INPUT TYPE=""SUBMIT"" VALUE=""" & GLS_TextSearch & """ CLASS=""XcBtn""></TD></TR>"
    Response.Write "</FORM>"
    ContentTail

    Response.Write "<br>"
    
    TableFoot
    DoPageFooter
%>
<SCRIPT LANGUAGE="JavaScript">
<!--
    document.EDITFORM.SearchFor.focus();
// -->
</SCRIPT>
<%
End Sub

Sub ShowSearchResults
    DoPageHeader
	AddJavaScriptHelp
            
    bRootable = False
	sSQL = "SELECT catID, catRootable, catDescription FROM tblAPCategories WHERE catID = " & SQLVal(lCatID)
	Set rsCurrentCat = gobjConnect.Execute(sSQL)
	If Not rsCurrentCat.Eof Then
		bRootable = EvalBool(rsCurrentCat("catRootable"))
	End If
	
	If 1 > lPageCurrent Then lPageCurrent = 1
	If lPageCurrent > iPageCount Then lPageCurrent = iPageCount

    PageHead(True)
        
	If Not rsAuction.EOF Then
		iPageCount = rsAuction.PageCount
		rsAuction.AbsolutePage = lPageCurrent
		
        If gbShowIcons Then
            OpenSpecialIconArray
        End If
        bFeaturedFlag = False
		
		
		If EvalBool(rsAuction("aucShowFeatured")) Then
			bFeaturedFlag = True
            If UCase(Trim(sView)) = "GALLERY" Then
                TableHead False,GLS_SearchFeaturedResults, True 
                ShowGallery(True)
            Else
                TableHead True,GLS_SearchFeaturedResults, True
                ShowList(true)
            End If
		End If
		
		If bFeaturedFlag Then
			Response.Write "&nbsp;"
		End If
				
		'*** All Auctions ***
		If rsAuction.AbsolutePage <= lPageCurrent AND NOT rsAuction.EOF Then
		    
            If UCase(Trim(sView)) = "GALLERY" Then
                TableHead False,gsSearchCellText, False
                ShowGallery(False)
            Else
                TableHead True,gsSearchCellText, False
                ShowList(False)
            End If  
		End If
			
        'If UCase(Trim(sView)) = "GALLERY" Then
            'ShowGallery
        'Else
            'ShowList
        'End If
        
        Response.Write "<br>"
        
		If (lPageCurrent > 1) Or (Not rsAuction.Eof) Then
        	iShowDataSetNavigation = True
        Else
        	iShowDataSetNavigation = False
        End If
	Else
	    ContentHead 3, False
		Response.Write "<TR><TD COLSPAN=""2""><CENTER>" & gsPlainTextOpen & GLS_SearchNoListings & gsPlainTextClose & "</FONT></CENTER></TD></TR>"
		ContentTail
	End If

    '*******PAGING
    If iShowDataSetNavigation Then
        iLowRange = RoundDownToNearest(lPageCurrent, 10)
        If iLowRange < 1 Then
           iLowRange = 1
        End If
        iHighRange = iLowRange + 9
		Response.Write "<TABLE CELLPADDING=""2"" CELLSPACING=""0"" BORDER=""0"" width=""" & gsTableWidth & """>"
		Response.Write "<TR><TD ALIGN=""RIGHT"">"
		Response.Write "<DIV CLASS=""APPagingNav"">" & gsPageNavOpen

        If lPageCurrent > 1 Then
            Response.Write "<A HREF=""APSearch.asp?page=" & lPageCurrent - 1 & sURLString & "&View=" & sView & """><img src=""APImages/APpnPrevious.gif"" alt=""" & GLS_TextPrevious & """ border=""0"" align=""absmiddle""></A>"
        Else
        	Response.Write "<a><img src=""APImages/APpnPrevious.gif"" alt=""" & GLS_TextPrevious & """ border=""0"" align=""absmiddle""></a>"
        End If

        If iLowRange >= 10 Then
           Response.Write "&nbsp;&nbsp;<A HREF=""APSearch.asp?&page=" & iLowRange - 1 & sURLString & "&View=" & sView & """>-</A>"
        End If

        sTemp = "&nbsp;"
        iPage = iLowRange
        Do While (iPage < iHighRange + 1) And (iPage <= rsAuction.PageCount)
           If iPage <> lPageCurrent Then
              sTemp = sTemp & "<A HREF=""APSearch.asp?page=" & iPage & sURLString & "&View=" & sView & """>" & iPage & "</A>&nbsp;&nbsp;"
           Else
              sTemp = sTemp & "<a><b>" & iPage & "</b></a>&nbsp;&nbsp;"
           End If
           iPage = iPage + 1
        Loop
        sTemp = sTemp & ""
        Response.Write "&nbsp;&nbsp;" & sTemp

        If rsAuction.PageCount > iHighRange Then
           Response.Write "&nbsp;&nbsp;<A HREF=""APSearch.asp?page=" & iHighRange + 1 & sURLString & "&View=" & sView & """>+</A>"
        End If
        If Not rsAuction.Eof Then
        	Response.Write "&nbsp;&nbsp;<A HREF=""APSearch.asp?page=" & lPageCurrent + 1 & sURLString & "&View=" & sView & """><img src=""APImages/APpnNext.gif"" alt=""" & GLS_TextNext & """ border=""0"" align=""absmiddle""></A>"
        Else
        	Response.Write "&nbsp;&nbsp;<a><img src=""APImages/APpnNext.gif"" alt=""" & GLS_TextNext & """ border=""0"" align=""absmiddle""></a>"
        End If
        Response.Write gsPageNavClose
        Response.Write "</DIV></TD></TR>"
        Response.Write "</TABLE><br>"
    End If
	
    TableFoot
    DoPageFooter
End Sub

Sub ShowList(pbFeatured)

    ContentHead 3, pbFeatured
    Response.Write "<TR bgcolor=""" & gsColTitleColor & """>"
    Response.Write "<TD WIDTH=""4%"">" & gsColTitleOpen & "<div class=""APSortBy""><a href=""APSearch.asp?SortBy=" & sTypeSort &  sURLString & """>"  & GLS_SearchAucTypeTitle  & "</a>&nbsp;" & sTypeColImg & "</div>" & gsColTitleClose & "</TD>"
    If gbShowListBonus Then
        Response.Write "<TD WIDTH=""5%"" ALIGN=""CENTER"">" & gsColTitleOpen & GLS_SearchBonusTitle & gsColTitleClose & "</TD>"
    End If
    Response.Write "<td width=""5%"" align=""center"">&nbsp;</td>"
    Response.Write "<TD WIDTH=""44%"">" & gsColTitleOpen & "<div class=""APSortBy""><a href=""APSearch.asp?SortBy=" & sTitleSort  & sURLString & """>"  & GLS_SearchItemTitle  & "</a>&nbsp;" & sTitleColImg & "</div>" & gsColTitleClose & "</TD>"
    If gbShowListCurrBid Then
        Response.Write "<TD WIDTH=""15%"">" & gsColTitleOpen & "<div class=""APSortBy""><a href=""APSearch.asp?SortBy=" & sCurrBidSort  & sURLString & """>"  & GLS_SearchCurrBidTitle  & "<a>&nbsp;" & sCurrBidColImg & "</div>" & gsColTitleClose & "</TD>"
    End If
    If gbShowListBidCount Then
        Response.Write "<TD WIDTH=""4%"">" & gsColTitleOpen & "<div class=""APSortBy""><a href=""APSearch.asp?SortBy=" & sBidsSort  & sURLString & """>"  & GLS_SearchNumBidsTitle  & "</a>&nbsp;" & sBidsColImg & "</div>" & gsColTitleClose & "</TD>"
    End If
    Response.Write "<TD WIDTH=""23%"" ALIGN=""RIGHT"">" & gsColTitleOpen & "<div class=""APSortBy""><a href=""APSearch.asp?SortBy=" & sClosesSort  & sURLString & """>" & GLS_SearchClosesTitle  & "</a>&nbsp;" & sClosesColImg & "</div>" & gsColTitleClose & "</TD>"
    Response.Write "</TR>"
    bSwitch = TRUE
    
    If pbFeatured Then
        bFeatured = True
        Do While (Not rsAuction.Eof) And (rsAuction.AbsolutePage <= lPageCurrent) AND (bFeatured)
            bFeatured = EValBool(rsAuction("aucShowFeatured"))
            ListDetailLine
        	rsAuction.MoveNext
        	If NOT rsAuction.Eof Then
			bFeatured = EvalBool(rsAuction("aucShowFeatured"))
    		Else
    			bFeatured = False
    		End If
        Loop
    Else
        Do While (Not rsAuction.Eof) And (rsAuction.AbsolutePage <= lPageCurrent)
            ListDetailLine
        	rsAuction.MoveNext
        Loop
    End If
    ContentTail
End Sub

Sub ListDetailLine
    lAucID = FVal(rsAuction("aucID"))
    sAucType = UCASE("" & rsAuction("aucType"))
    vAucAvailable = rsAuction("aucAvailable")
    vAucClose = rsAuction("aucClose")
    fAucCurrentBid = FVal(rsAuction("aucCurrentBid"))
    sThumbnail = "" & rsAuction("aucThumbnail")
    lAlhlID = FVal(rsAuction("aucAlhlID"))
    
    sColor = AlternateTag(bSwitch, gsAltColorOne, gsAltColorTwo)
    If lAlhlID > 0 Then
        sColor = HighlightColor(lAlhlID, sColor)
    End If
    
	Response.Write "<TR BGCOLOR=""" & sColor & """>"
	Response.Write "<TD>" & AuctionTypeIcon(sAucType) & "</TD>"

	'*****Bonus Start	
	If gbShowListBonus Then						
        Response.Write "<td>"
        'Gallery
    	If gbGalleryView And gbUseGallery And EvalBool(rsAuction("aucShowInGallery")) Then
    		Response.Write "<IMG BORDER=""0"" SRC=""APImages/APGallery.gif"" ALT=""" & gsAddGalleryTitle & """>"
    	Else
    		Response.Write "<IMG SRC=""APImages/pix.gif"" border=""0"" WIDTH=""15"" height=""10"">"
    	End If
    	'Featured
    	If EvalBool(rsAuction("aucShowFeatured")) Then
    		Response.Write "<IMG BORDER=""0"" SRC=""APImages/APFeatured.gif"" ALT=""" & gsAddFeatured & """>"
    	Else
    		Response.Write "<IMG SRC=""APImages/pix.gif"" border=""0"" WIDTH=""15"" height=""10"">"
    	End If
    	'Premiere
    	If EvalBool(rsAuction("aucShowInPremiere")) Then
    		Response.Write "<IMG BORDER=""0"" SRC=""APImages/APPremiere.gif"" ALT=""" & gsAddPremiere & """>"
    	Else
    		Response.Write "<IMG SRC=""APImages/pix.gif"" border=""0"" WIDTH=""15"" height=""10"">"
    	End If
    	'Icon
    	If FVal(rsAuction("aucIconName")) > 0 And gbShowIcons Then
    		Response.Write OutputIcon(FVal(rsAuction("aucIconName")))
    	Else
    		Response.Write "<IMG SRC=""APImages/pix.gif"" border=""0"" WIDTH=""15"" height=""10"">"
    	End If
    	Response.Write "</TD>"
	End If
	'**Bonus End
		
	Response.Write "<TD>"
	'If gbThumbnails And gbGalleryView And gbGalleryThumbsInAll Then
	If gbThumbnails And gbGalleryThumbsInAll Then    
	    If Len(sThumbnail) > 0 Then
    	    If (gbUseGallery And EvalBool(rsAuction("aucShowInGallery"))) Or (Not gbUseGallery) Then
    	        Response.Write "<IMG BORDER=""0"" SRC=""" & gsUserImagesFolder & "/" & sThumbnail & """ ALT=""" & gsAddGalleryTitle & """>"
    	    Else
                Response.Write "&nbsp;"
            End If
    	Else
    	    Response.Write "&nbsp;"
    	End If
    End If
    Response.Write "</td>"
	
	'**Title
	'Response.Write("<TD><DIV CLASS=""APLink"">" & gsAuctionListingOpen & "<A HREF=""APViewItem.asp?ID=" & lAucID & """>")
	Response.Write "<TD>" & gsAuctionListingOpen & "<A HREF=""APViewItem.asp?ID=" & lAucID & """>"
	If EvalBool(rsAuction("aucShowBold")) Then
		Response.Write "<B>" & rsAuction("aucTitle") & "</B>"
	Else
		Response.Write "" & rsAuction("aucTitle")
	End If
	Response.Write "</A>" & gsAuctionListingClose
	If OutMatch(True, giHotCriteria = 1, FVal(rsAuction("aucBidCounts")), FVal(rsAuction("aucViewCount"))) > giHotCount Then
		Response.Write "&nbsp;<IMG BORDER=""0"" SRC=""APImages/APHot.gif"" ALT=""" & gsHotItem & """>"
	End If
	If (Len(Trim(rsAuction("aucImageURL"))) > 0) OR EvalBool(rsAuction("aucIMGFlag")) Then
		Response.Write "&nbsp;<IMG BORDER=""0"" SRC=""APImages/APImage.gif"" ALT=""" & gsImage & """>"
	End If
	If FVal(rsAuction("aucReserve")) > 0 Then
			If fAucCurrentBid >= FVal(rsAuction("aucReserve")) Then
			Response.Write "&nbsp;<IMG BORDER=""0"" SRC=""APImages/APReserveMet.gif"" alt=""" & GLS_ViewReserveMet & """>"
		Else 
			Response.Write "&nbsp;<IMG BORDER=""0"" SRC=""APImages/APReserveNotMet.gif"" alt=""" & GLS_ViewReserveNotMet & """>"
		End If
	End If			
	If (FVal(rsAuction("aucFlashBuy")) > 0) AND (NOT vAucClose < NOW) Then			
		If NOT (fAucCurrentBid >= FVal(rsAuction("aucReserve"))) Then
			Response.Write "&nbsp;<IMG BORDER=""0"" SRC=""APImages/APFlashBuy.gif"" ALT=""" & GLS_TextFlashBuy & """>"
		Else
			If NOT (FVal(rsAuction("aucBidCounts")) > 0) OR gbFlashBuyAlways Then
				Response.Write "&nbsp;<IMG BORDER=""0"" SRC=""APImages/APFlashBuy.gif"" ALT=""" & GLS_TextFlashBuy & """>"
			End If
		End If
	End If
	If giNewHours >= DateDiff("h", vAucAvailable, Now) Then
	    Response.Write "&nbsp;<IMG BORDER=""0"" SRC=""APImages/APNew.gif"" ALT=""" & gsNewAuctions & """>"
	End If

	Response.Write "</TD>"
				
	'**Current Bid
	If gbShowListCurrBid Then
		Response.Write "<TD>" & gsAuctionListingOpen
		Select Case sAucType
		    Case "Q":
		        If gsRfqShowBidAmount = "N" Then
		            Response.Write GLS_TextNotAvail
		        Else
					If fAucCurrentBid <= 0 Then
					    If gbHideStartBidInList Then
					        Response.Write GLS_TextNoCurrentBid
					    Else
						    Response.Write DispCurrency(rsAuction("aucStartingBid"))
						End If
					Else	
						Response.Write DispCurrency(fAucCurrentBid)
					End If
		        End If
		    Case Else
				If fAucCurrentBid <= 0 Then
				    If gbHideStartBidInList Then
				        Response.Write GLS_TextNoCurrentBid
				    Else
					    Response.Write DispCurrency(rsAuction("aucStartingBid"))
					End If
				Else	
					Response.Write DispCurrency(fAucCurrentBid)
				End If
		End Select
		Response.Write gsAuctionListingClose & "</TD>"
	End If
	
	'**Bids
	If gbShowListBidCount Then
		Response.Write "<TD>" & gsAuctionListingOpen
		Response.Write FVal(rsAuction("aucBidCounts"))
		Response.Write gsAuctionListingClose & "</TD>"
	End If
				
	'**Closes
	Response.Write "<TD ALIGN=""RIGHT"">" & gsAuctionListingOpen
	
	If gbShowListCloseAsTimeLeft AND vAucClose > Now Then
	    sCloseText = GetTimeLeft(vAucClose)
	Else
	    sCloseText =  "" & DispShortDateTime(vAucClose)
	End If    
	
	If DateDiff("n", Now, vAucClose) <= giClosingSoon Then
		Response.Write gsClosingSoonOpen & sCloseText & gsClosingSoonClose
	Else
		Response.Write sCloseText
	End If
	Response.Write gsAuctionListingClose & "</TD></TR>"
End Sub

Sub ShowGallery(pbFeatured)
    Dim sTitleRow, sThumbRow, sCloseRow, sBidRow
    iCurrentCol = 1
	iNumCols = giMainStdGalleryCols
	iColWidth = CLng((1 / iNumCols) * 100)
	bFirstIteration = True
	ContentHead 0, pbFeatured
	
	bContinue = True
	Do While bContinue 
	    lAucID = FVal(rsAuction("aucID"))
	    sAucType = UCASE("" & rsAuction("aucType"))
	    vAucAvailable = rsAuction("aucAvailable")
	    vAucClose = rsAuction("aucClose")
	    fAucCurrentBid = FVal(rsAuction("aucCurrentBid"))
	    sTitle = "" & rsAuction("aucTitle")
	    bBold = EValBool(rsAuction("aucShowBold"))
	    sThumbnail = "" & rsAuction("aucThumbnail")
	    lAlhlID = FVal(rsAuction("aucAlhlID"))
	    
        If bFirstIteration Then
            Response.Write "<tr><td colspan=""" & iNumCols & """>&nbsp;</td></tr>"
            bFirstIteration = False
        End If
        sColor = gsPageBGColor
	    If lAlhlID > 0 Then
	        sColor = HighlightColor(lAlhlID, sColor)
	    Else
	        sColor = gsPageBGColor
	    End If

	    If iCurrentCol = 1 Then
		    sThumbRow = vbCrLf & "<TR>"
		    sTitleRow = vbCrLf & "<TR>"
		    sCloseRow = vbCrLf & "<tr>"
		    If gbShowListCurrBid Then
		        sBidRow = vbCrLf & "<tr>"
		    End If
		End If
		
		'Thumbnail Row Construction
	    sThumbRow = sThumbRow & "<td align=""center"" valign=""center"" width=""" & iColWidth & "%""  bgcolor=""" & sColor & """>"
        If Len(sThumbnail) > 0 Then
            sThumbRow = sThumbRow & "<A HREF=""APViewItem.asp?ID=" & lAucID & """><img src=""" & gsUserImagesFolder & "/" & sThumbnail & """ alt=""" & gsAddGalleryTitle & """  border=""0""></a>"
        Else
            sThumbRow = sThumbRow & "<img src=""APImages/APGallery.gif"">"
        End If
        sThumbRow = sThumbRow & "</td>" & vbCrLf
        
        'Title Row Construction
		sTitleRow = sTitleRow & "<td align=""center"" valign=""top"" width=""" & iColWidth & "%""  bgcolor=""" & sColor & """><DIV CLASS=""APLink"">" & gsAuctionListingOpen
		If bBold And gbDefShowBold Then sTitleRow = sTitleRow & "<b>"
		sTitleRow = sTitleRow & "<A HREF=""APViewItem.asp?ID=" & lAucID & """>" & sTitle  & "</A>" & gsAuctionListingClose 
		If bBold And gbDefShowBold Then sTitleRow = sTitleRow & "</b>"
		sTitleRow = sTitleRow & "</DIV></td>" & vbCrLf

		'Close Row Construction
		sCloseRow = sCloseRow & "<td align=""center"" width=""" & iColWidth & "%"">" & gsPlainTextOpen & "<small>" & GLS_SearchGalleryTimeLeftText & "<b>" & GetTimeLeft(vAucClose) & "</b></small>" & gsPlainTextClose & "</TD>" & vbCrLf

		'Current Bid Row Construction
		If gbShowListCurrBid Then
			sBidRow = sBidRow & "<TD align=""center"">" & gsAuctionListingOpen & GLS_ViewGalleryCurrBid
			Select Case sAucType
			    Case "Q":
			        If gsRfqShowBidAmount = "N" Then
			            sBidRow = sBidRow & GLS_TextNotAvail
			        Else
						If fAucCurrentBid <= 0 Then
						    If gbHideStartBidInList Then
							    sBidRow = sBidRow & GLS_TextNoCurrentBid
							Else
							    sBidRow = sBidRow & DispCurrency(rsAuction("aucStartingBid"))
							End If
						Else	
							sBidRow = sBidRow & DispCurrency(fAucCurrentBid)
						End If
			        End If
			    Case Else
					If fAucCurrentBid <= 0 Then
					    If gbHideStartBidInList Then
						    sBidRow = sBidRow & GLS_TextNoCurrentBid
						Else
						    sBidRow = sBidRow & DispCurrency(rsAuction("aucStartingBid"))
					    End If
					Else	
						sBidRow = sBidRow & DispCurrency(fAucCurrentBid)
					End If
			End Select
			sBidRow = sBidRow & gsAuctionListingClose & "</TD>"
		End If
		
		If iCurrentCol = iNumCols Then
		    sThumbRow = sThumbRow & "</TR>"
		    sTitleRow = sTitleRow & "</TR>"
		    sCloseRow = sCloseRow & "</tr>"
		    If gbShowListCurrBid Then
		        sBidRow = sBidRow & "</tr>"
		    End If
		    Response.Write sThumbRow & vbCrLf
		    Response.Write sTitleRow & vbCrLf
		    Response.Write sCloseRow & vbCrLf
		    If gbShowListCurrBid Then
		        Response.Write sBidRow & vbCrLf
		    End If
		    Response.Write "<tr><td colspan=""" & iNumCols & """>&nbsp;</td></tr>"
		    iCurrentCol = 1
		Else
		    iCurrentCol = iCurrentCol + 1
		End If
		rsAuction.MoveNext
		If NOT rsAuction.EOF Then
		    If (rsAuction.AbsolutePage <= lPageCurrent) Then
		        If (pbFeatured AND EvalBool(rsAuction("aucShowFeatured"))) OR (NOT pbFeatured) Then 
		            bContinue = True
		         Else
		            bContinue = False
		         End If      
		    Else
		        bContinue = False
		    End If    
		Else
		    bContinue = False
		End If    
	Loop
	If (iCurrentCol - 1 < iNumCols) And (iCurrentCol > 1) Then
	    For iIndex = iCurrentCol To iNumCols
	        sThumbRow = sThumbRow & "<td width=""" & iColWidth & "%"">&nbsp;</td>"
	        sTitleRow = sTitleRow & "<td width=""" & iColWidth & "%"">&nbsp;</td>"
	        sCloseRow = sCloseRow & "<td width=""" & iColWidth & "%"">&nbsp;</td>"
	        If gbShowListCurrBid Then
	            sBidRow = sBidRow & "<td width=""" & iColWidth & "%"">&nbsp;</td>"
	        End If
	    Next
	    sThumbRow = sThumbRow & "</tr>"
	    sTitleRow = sTitleRow & "</tr>"
	    sCloseRow = sCloseRow & "</tr>"
	    If gbShowListCurrBid Then
	        sBidRow = sBidRow & "</tr>"
	    End If
	    Response.Write sThumbRow & vbCrLf
	    Response.Write sTitleRow & vbCrLf
	    Response.Write sCloseRow & vbCrLf
	    If gbShowListCurrBid Then
	        Response.Write sBidRow & vbCrLf
	    End If
	    Response.Write "<tr><td colspan=""" & iNumCols & """>&nbsp;</td></tr>"
	End If
	ContentTail
End Sub

Sub DisplayViewMenu
    'Display the VIEW menu (Normal View vs. Gallery View)
	'Response.Write "VIEW = " & sView & "<BR>"
	'Response.Write "DefVIEW = " & gsDefaultView & "<BR>"
	
	sTempColor = gsTabUnselectedColor
	Response.Write "<TABLE BORDER=""0"" CELLPADDING=""1"" CELLSPACING=""0"" WIDTH=""" & gsTableWidth & """>"
	
	'**Main View
	If sView <> "GALLERY" Then 
		sTempColor = gsTabSelectedColor
	End If
	Response.Write "<TR>"
	Response.Write "<TD BGCOLOR=""" & sTempColor & """ WIDTH=""25%"">"
	If sView <> "GALLERY" Then
	    Response.Write gsSelectedTabTextOpen & "<A HREF=""APSearch.asp?VIEW=MAIN" & sURLString & "&page=" & lPageCurrent & """>" & GLS_ViewMain & "</A>" & gsSelectedTabTextClose
	Else
	    Response.Write gsUnSelectedTabTextOpen & "<A HREF=""APSearch.asp?VIEW=MAIN" & sURLString & "&page=" & lPageCurrent & """>" & GLS_ViewMain & "</A>" & gsUnSelectedTabTextClose
    End If
	Response.Write "</TD>"
	
	Response.Write "<TD BGCOLOR=""" & gsEmptyColor & """><FONT SIZE=""1"">&nbsp;</FONT></TD>"
	sTempColor = gsTabUnselectedColor
	
	'**Gallery View
	If sView = "GALLERY" Then 
		sTempColor = gsTabSelectedColor
	End If
	Response.Write "<TD BGCOLOR=""" & sTempColor & """ WIDTH=""25%"">"
	If sView = "GALLERY" Then
	    Response.Write gsSelectedTabTextOpen & "<A HREF=""APSearch.asp?VIEW=GALLERY" & sURLString & "&page=" & lPageCurrent & """>" & GLS_ViewGallery & "</A>" & gsSelectedTabTextClose
	Else
	    Response.Write gsUnSelectedTabTextOpen & "<A HREF=""APSearch.asp?VIEW=GALLERY" & sURLString & "&page=" & lPageCurrent & """>" & GLS_ViewGallery & "</A>" & gsUnSelectedTabTextClose
    End If
	Response.Write "</TD>"
	
	Response.Write "<TD BGCOLOR=""" & gsEmptyColor & """><FONT SIZE=""1"">&nbsp;</FONT></TD>"
	sTempColor = gsTabUnselectedColor
	
	'**Closed User Auctions
	Response.Write "<TD COLSPAN=""5"" WIDTH=""40%"" BGCOLOR=""" & gsEmptyColor & """>&nbsp;</TD>"
	
	Response.Write "<TD BGCOLOR=""" & gsEmptyColor & """><FONT SIZE=""1"">&nbsp;</FONT></TD>"
	sTempColor = gsTabUnselectedColor
	
	Response.Write "</TR>"
	
	Response.Write "<TR BGCOLOR=""" & gsTabSelectedColor & """><TD COLSPAN=""10"">"
	Response.Write "<IMG BORDER=""0"" SRC=""APImages/pix.gif"" WIDTH=""1"" HEIGHT=""1"">"
	Response.Write "</DIV></TD></TR>"
	
	Response.Write "</TABLE>"
End Sub

Sub DoRegionDropDown
	OpenDBConn
	sSQL = "SELECT * FROM tblAPRegions ORDER BY rgnDescription"
	Set rsRegion = gobjConnect.Execute(sSQL)
	Response.Write "<SELECT NAME=""RegionID"">"
	If Not rsRegion.EOF Then
		Response.Write "<OPTION VALUE=""0"">" & GLS_TextAllRegions & "</OPTION>"
		Do While Not rsRegion.EOF
			Response.Write "<OPTION VALUE=""" & rsRegion("rgnID") & """" &  OutMatch(rsRegion("rgnID"), lSearchRegion, "SELECTED", "") &  ">" & rsRegion("rgnDescription") & "</OPTION>" & chr(10) & chr(13)
			rsRegion.MoveNext
		Loop
	Else
		Response.Write "<OPTION VALUE=""0"">" & gsAddNoRegion & "</OPTION>"
	End If
	Response.Write "</SELECT>"
	rsRegion.Close
	Set rsRegion = Nothing
End Sub

Function GetTimeLeft(pvDate)
    Dim iDays, iHours, iMins, iSecs
    iDays = 0
    iHours = 0
    iMins = 0
    iSecs = 0
    
    CISecPerDay = 86400
    CISecPerHour = 3600
    CISecPerMin = 60

    lTotalSecs = DateDiff("s", Now, pvDate)
    If (lTotalSecs >= CISecPerDay) Then
        iDays = (lTotalSecs \ CISecPerDay)
        lTotalSecs = lTotalSecs - (iDays * CISecPerDay)
    End If
    If (lTotalSecs >= CISecPerHour) Then
        iHours = (lTotalSecs \ CISecPerHour)
        lTotalSecs = lTotalSecs - (iHours * CISecPerHour)
    End If
    If (lTotalSecs >= CISecPerMin) Then
        iMins = (lTotalSecs \ CISecPerMin)
        lTotalSecs = lTotalSecs - (iMins * CISecPerMin)
    End If
    
    iSecs = lTotalSecs
    
    sTimeLeftString = ""
    bRemainder = False
    If iDays > 0 Then 
        sTimeLeftString = sTimeLeftString & iDays & GLS_TimerDays & "&nbsp;"
        bRemainder = True
    End If
    If iHours > 0 OR bRemainder Then 
        sTimeLeftString = sTimeLeftString & iHours & GLS_TimerHours & "&nbsp;"
        bRemainder = True
    End If
    If iMins > 0 OR bRemainder Then 
        sTimeLeftString = sTimeLeftString & iMins & GLS_TimerMinutes & "&nbsp;"
        bRemainder = True
    End If
    If iSecs > 0 OR bRemainder Then 
        sTimeLeftString = sTimeLeftString & iSecs & GLS_TimerSeconds
    End If
    
    GetTimeLeft = sTimeLeftString
End Function

Function GetRegionName(piRegion)
    sSQL = "SELECT rgnDescription FROM tblAPRegions WHERE rgnID = " & SQLVal(piRegion)
	set rsRegion = gobjConnect.Execute(sSQL)
	If Not rsRegion.EOF Then
	    GetRegionName = rsRegion("rgnDescription")
	Else 
		GetRegionName = gsNoRegion 
	End If
	rsRegion.Close
	set rsRegion = Nothing
End Function

Function GetSearchQueryPart(psArSearchWords, psWordOperator, psDBField)
   sTempSQL = ""
   For lLoop = 0 to Ubound(psArSearchWords)
      If Len(Trim(psArSearchWords(lLoop))) > 0 Then
         If iFirstIteration Then
            sSearchSQL = sSearchSQL & " AND ("
            iFirstIteration = False
         Else
            sTempSQL = sTempSQL & " " & psWordOperator & " "
         End If
         sTempSQL = sTempSQL & "( " & psDBField & " Like " & SQLStr(gsSQLWildCardChar & psArSearchWords(lLoop) & gsSQLWildCardChar ) & " )"
      End If
   Next
   GetSearchQueryPart = sTempSQL
End Function

Function ValidateSearch
    If Len(sSearchFor) > 0 Then
        ValidateSearch = True
    ElseIf Len(sSearchName) > 0 Then
        ValidateSearch = True
    ElseIf Len(sSearchSerial) > 0 Then
        ValidateSearch = True
    ElseIf Len(sSearchPart) > 0 Then
        ValidateSearch = True
    ElseIf Len(sSearchProduct) > 0 Then
        ValidateSearch = True
    ElseIf Len(sSearchReference) > 0 Then
        ValidateSearch = True
    ElseIf lRegionID > 0 Then
        ValidateSearch = True
    Else
        ValidateSearch = False
    End If
End Function

Sub OpenSpecialIconArray
    sSQLIcons = "SELECT * FROM tblAPIcons"
    Set rsIcons = Server.CreateObject("ADODB.Recordset")
    rsIcons.Open sSQLIcons, gobjConnect, 3, 2, &H0001 'adOpenForwardOnly, adLockReadOnly, adCmdText
    If Not rsIcons.EOF THen
        sArSpecialIcons = rsIcons.GetRows
    End If
    rsIcons.Close
    Set rsIcons = Nothing
End Sub

Function OutputIcon(plIconID)
    Dim sIcon
    sIcon = ""
    If IsArray(sArSpecialIcons) Then
        For iIndex = 0 To UBound(sArSpecialIcons, 2)
            If sArSpecialIcons(0, iIndex) = plIconID Then
                sIcon = "<img src=""APIcons/" & sArSpecialIcons(2, iIndex) & """ alt=""" & sArSpecialIcons(1, iIndex) & """>"
            End If
        Next
    End If
    OutputIcon = sIcon
End Function

Sub ContentHead(piInnerTblPadding, pbFeaturedColor)
   Response.Write "<TABLE BORDER=""0"" CELLPADDING=""1"" CELLSPACING=""0"" BGCOLOR=""" & OutMatch(True, pbFeaturedColor, gsFeaturedBoxColor, gsBoxColor) & """WIDTH=""" & gsDefaultTableWidth & """>"
   Response.Write "<TR><TD>"
   Response.Write "<TABLE BORDER=""0"" CELLPADDING=""" & FVal(piInnerTblPadding) & """ CELLSPACING=""0"" BGCOLOR=""" & gsPageBGColor & """ WIDTH=""100%"">"
End Sub

Sub ContentTail
   Response.Write "</TABLE>"
   Response.Write "</TD></TR>"
   Response.Write "</TABLE>"
End Sub

Sub PageHead(pbResults)
	Response.Write "<TABLE BORDER=""0"" CELLPADDING=""3"" CELLSPACING=""0"" WIDTH=""" & gsTableWidth & """>"
	Response.Write "<TR><TD COLSPAN=""1"" ALIGN=""LEFT"" VALIGN=""BOTTOM"">" & gsCategoryTreeOpen
	Response.Write DoNavTree(lCatID, OutMatch(True, pbResults, gsSearchTitle & gsSearchResults, gsSearchAdvancedTitle))
	Response.Write gsCategoryTreeClose & "</TD>"
	Response.Write "<TD ALIGN=""RIGHT"" VALIGN=""BOTTOM"">&nbsp;"
	Response.Write "</TD></TR>"
    Response.Write "</table>"
    
    If gbGalleryView AND pbResults Then '**Tab Menu
		DisplayViewMenu
	End If
	
	If pbResults Then
        '**Time Stamp
    	Response.Write "<TABLE BORDER=""0"" CELLPADDING=""3"" CELLSPACING=""0"" WIDTH=""" & gsTableWidth & """>"
    	Response.Write "<TR><TD COLSPAN=""2"" VALIGN=""BOTTOM"">"
    	Response.Write gsTimeTextOpen & gsCurrentTimeText & "<B>" & DispShortDateTime(NOW) & "</B>" & gsTimeTextClose
    	Response.Write "</TD></TR>"
    	Response.Write "</TABLE>"
    End If	
	
End Sub

Sub TableHead(pbIcons,psLabel,pbFeatured)
    Response.Write "<TABLE BORDER=""0"" CELLPADDING=""0"" CELLSPACING=""0"" WIDTH=""" & gsTableWidth & """>"
	Response.Write "<TR>"
	Response.Write "<TD bgcolor=""" & OutMatch(False, pbFeatured, gsTabColor, gsFeaturedTabColor) & """>" & gsTabTextOpen & psLabel & gsTabTextClose & "</TD>"
	Response.Write "<TD bgcolor=""" & OutMatch(False, pbFeatured, gsEmptyColor, gsFeaturedEmptyColor) & """ WIDTH=""65%"" ALIGN=""RIGHT"">" & gsPlainTextOpen & "<SMALL><B>"
	If pbIcons Then
	    If gbUseFeatured And pbFeatured Then
            Response.Write "<IMG BORDER=""0"" SRC=""APImages/APFeatured.gif"" ALT=""" & gsAddFeatured & """> = " & gsAddFeatured  & "&nbsp;&nbsp;"
        End If
        If gbUsePremiere Then
            Response.Write "<IMG BORDER=""0"" SRC=""APImages/APPremiere.gif"" ALT=""" & gsAddPremiere & """> = " & gsAddPremiere & "&nbsp;&nbsp;"
        End If
        If gbUseGallery Then
            Response.Write "<IMG BORDER=""0"" SRC=""APImages/APGallery.gif"" ALT=""" & gsAddGalleryTitle & """> = " & gsAddGalleryTitle & "&nbsp;&nbsp;"
        End If
    Else
        Response.Write "&nbsp;"
    End If
	Response.Write "</B></SMALL>" & gsPlainTextClose & "</TD></TR>"
	Response.Write "<TR><TD COLSPAN=""2"" bgcolor=""" & OutMatch(False, pbFeatured, gsTabColor, gsFeaturedTabColor) & """ HEIGHT=""2""><IMG BORDER=""0"" SRC=""APImages/pix.gif"" WIDTH=""1"" HEIGHT=""2""></TD></TR>"
    Response.Write "</TABLE>"
End Sub

Sub TableFoot
    If gbShowNavBarOnOther Then
    	ShowNavBar bRootable, lCatID
    End If
End Sub
%>